虽然上一节让我们开始了解如何表示数学行为，但它并不与物理行为有任何关联。在本节中，我们将探讨如何构建能够体现物理行为建模的模型。在此过程中，我们将重点介绍一些我们可以利用的语言特性，这些特性不仅能使这些模型与物理和工程领域相联系，而且正如我们即将看到的，它们甚至能帮助我们避免错误。

让我们从下面这个例子开始：

model NewtonCooling "An example of Newton's law of cooling"
  parameter Real T_inf "Ambient temperature";
  parameter Real T0 "Initial temperature";
  parameter Real h "Convective cooling coefficient";
  parameter Real A "Surface area";
  parameter Real m "Mass of thermal capacitance";
  parameter Real c_p "Specific heat";
  Real T "Temperature";
initial equation
  T = T0 "Specify initial value for T";
equation
  m*c_p*der(T) = h*A*(T_inf-T) "Newton's law of cooling";
end NewtonCooling;

正如我们在讨论简单一阶系统时所举的例子中看到的那样，前面的例子包含了一个模型定义，其中包含了变量和方程。

不过，这次我们首次见到“parameter”这个词。一般来说，“parameter”这个关键字用于表示那些在模拟之前其值已知的变量。更确切地说，“parameter”是一个关键字，用于指定变量的可变性。这将在“可变性”一节中进行更深入的讨论。但就目前而言，我们可以把参数看作一个必须提供其值的变量。

看我们的“牛顿冷却”示例，可以看到有五个参数：T_inf、T0、h、A、m 和 c_p。我们无需费心解释这些变量是什么，因为模型本身为每个参数都包含了一个描述性字符串。目前，这些参数都没有值，但我们很快会回到这个话题。与我们迄今为止看到的所有变量一样，这些参数都是“实数”类型。

让我们来审视一下这个模型的其余部分。接下来的变量是 T（同样为实数）。由于这个变量没有参数限定符，其值由模型中的方程来确定。

接下来我们看到两个方程部分。第一个是初始方程部分，它指定了变量T 应如何初始化。显然，T 的初始值将是（我们）为参数 T0 给定的任何值。

另一个方程是控制 T 行为的微分方程。从数学角度来说，我们可以将此方程表示为：

但在 Modelica 中，我们将其表述为：

m*c_p*der(T) = h*A*(T_inf-T)

请注意，这与我们在“简单一阶系统示例”的“一阶模型”中所看到的方程式并无太大差异。

有一点值得注意的是，在我们的“牛顿冷却”示例中，方程的左侧包含了一个表达式。在 Modelica 中，并非每个方程都必须是针对单个变量的显式方程。一个方程可以在等号的两侧包含任意表达式。编译器的任务是确定如何利用这些方程来求解方程中包含的变量。

我们的“牛顿冷却”示例与“一阶模型”之间的另一个区别在于，我们可以独立调整不同的参数值。此外，这些参数值与材料的物理可测量特性或环境条件相关联。换句话说，这个版本比“一阶模型”中所使用的简单数学关系更具物理性，因为它与物理特性有关。

现在，我们无法直接使用牛顿冷却模型进行运行，因为它缺少六个参数的值。为了创建一个可以进行模拟的模型，我们需要提供这些参数的值，例如：

model NewtonCoolingWithDefaults "Cooling example with default parameter values"
  parameter Real T_inf=25 "Ambient temperature";
  parameter Real T0=90 "Initial temperature";
  parameter Real h=0.7 "Convective cooling coefficient";
  parameter Real A=1.0 "Surface area";
  parameter Real m=0.1 "Mass of thermal capacitance";
  parameter Real c_p=1.2 "Specific heat";
  Real T "Temperature";
initial equation
  T = T0 "Specify initial value for T";
equation
  m*c_p*der(T) = h*A*(T_inf-T) "Newton's law of cooling";
end NewtonCoolingWithDefaults;

这里唯一的实质性区别在于，现在每个参数变量都有了指定的值。对于牛顿冷却模型，我们可以这样理解：由于它有 7 个变量（总共），而只有一个方程（请参阅初始化部分以了解为什么初始方程实际上不算在内），所以无法对其进行模拟。然而，从概念上讲，牛顿冷却默认模型有 7 个方程（其中 6 个来自指定参数变量的值 + 方程部分的一个方程）和 7 个未知数。

如果我们对“牛顿冷却默认模型”进行模拟，就能得到温度 T 的如下解值。

物理单位

正如本节中已经提到的那样，这些示例更具物理性，因为它们包含了与我们现实世界系统各个特性相对应的个别物理参数。然而，我们仍然有所欠缺。尽管这些变量代表了诸如温度、质量等物理量，但我们尚未明确赋予它们任何物理类型。

正如您可能已经猜到的那样，变量 T 表示的是温度。这一点在与该变量相关的描述性文本中已经明确说明了。此外，无需对我们的先前模型进行深入分析，就能确定 T0 和 T_inf 也必须是温度。

但像 h 或 A 这样的其他变量又代表什么呢？它们具体有何含义？更重要的是，这些方程在物理上是否是相互一致的呢？所谓物理上一致，是指方程的两边具有相同的物理单位（例如温度、质量、功率）。

我们可以通过将不同变量的物理单位直接包含在变量声明中来更严谨地表达这些单位，例如：

model NewtonCoolingWithUnits "Cooling example with physical units"
  parameter Real T_inf(unit="K")=298.15 "Ambient temperature";
  parameter Real T0(unit="K")=363.15 "Initial temperature";
  parameter Real h(unit="W/(m2.K)")=0.7 "Convective cooling coefficient";
  parameter Real A(unit="m2")=1.0 "Surface area";
  parameter Real m(unit="kg")=0.1 "Mass of thermal capacitance";
  parameter Real c_p(unit="J/(K.kg)")=1.2 "Specific heat";

  Real T(unit="K") "Temperature";
initial equation
  T = T0 "Specify initial value for T";
equation
  m*c_p*der(T) = h*A*(T_inf-T) "Newton's law of cooling";
end NewtonCoolingWithUnits;

请注意，现在每个变量声明都包含了文本（unit="..."），以便将物理单位与该变量关联起来。这个额外的文本的作用是为与该变量相关的单位属性指定一个值。属性是每个变量所具有的特殊属性。变量可以拥有的属性集取决于变量的类型（这将在即将讨论的“变量”部分中进行更详细的说明）。

乍一看，可能并不清楚为何要明确指定“单位”属性（例如，(unit="K")）会比直接在变量后的描述字符串中加上“温度”更好。实际上，甚至有人可能会认为这样做反而更糟糕，因为“温度”比仅仅用一个字母“K”来表示更具描述性。

然而，设置单位属性实际上是一种更为正式的处理方式，原因有二。其一，Modelica 规范为所有标准的国际单位属性（例如 K、kg、m）都定义了相关关系。这包括那些可以由其他基本单位组合而成的复杂单位类型（例如 N）。

另一个原因是，Modelica 规范还规定了如何计算复杂数学表达式的单位的相关规则。通过这种方式，Modelica 规范明确了对 Modelica 模型进行单位检查（以发现错误或物理不一致性）所需的一切内容。这对模型开发者来说是一个巨大的优势，因为添加单位不仅能使模型更加清晰，还能在出现错误时提供更有效的诊断信息。

物理类型

但说实话，对于我们的“NewtonCoolingWithUnits”示例代码，有一个缺点，那就是我们必须为每个变量重复输入单位属性的说明。此外，正如之前所提到的，“K”远不如“温度”那样具有描述性。

幸运的是，我们有两个问题都有一个简单的解决办法，因为 Modelica 允许我们定义派生类型。到目前为止，我们声明的所有变量都是实数类型。但实数类型的问题在于它可以表示任何东西（例如电压、电流、温度）。我们希望将范围缩小一些。这就是派生类型发挥作用的地方。为了了解如何定义派生类型以及如何在声明中使用它们，请看下面的示例：

model NewtonCoolingWithTypes "Cooling example with physical types"
  // Types
  type Temperature=Real(unit="K", min=0);
  type ConvectionCoefficient=Real(unit="W/(m2.K)", min=0);
  type Area=Real(unit="m2", min=0);
  type Mass=Real(unit="kg", min=0);
  type SpecificHeat=Real(unit="J/(K.kg)", min=0);

  // Parameters
  parameter Temperature T_inf=298.15 "Ambient temperature";
  parameter Temperature T0=363.15 "Initial temperature";
  parameter ConvectionCoefficient h=0.7 "Convective cooling coefficient";
  parameter Area A=1.0 "Surface area";
  parameter Mass m=0.1 "Mass of thermal capacitance";
  parameter SpecificHeat c_p=1.2 "Specific heat";

  // Variables
  Temperature T "Temperature";
initial equation
  T = T0 "Specify initial value for T";
equation
  m*c_p*der(T) = h*A*(T_inf-T) "Newton's law of cooling";
end NewtonCoolingWithTypes;

您可以将“Temperature=Real(unit="K", min=0)；”这一定义理解为：“我们定义了一个新的类型“Temperature”，它是内置类型“Real”的一种特化形式，具有开尔文（K）这样的物理单位，并且其最小可能值为 0”。

从这个例子中我们可以看出，一旦我们定义了一个像“温度”这样的物理类型，我们就可以使用它来声明多个变量（例如，T、T_inf 和 T0），而无需为每个变量指定单位或最小值属性。此外，我们还可以使用熟悉的名称“温度”来代替国际单位制中的“开尔文”。您可能会想知道在创建派生类型时还有哪些可用的属性。有关进一步的讨论，请参阅“内置类型”部分。

此时，您可能会觉得在每个模型中定义温度、对流系数、比热容和质量等参数的过程极其繁琐。如果确实有必要这样做的话，那的确会是如此。但请不要担心，这个问题有一个简单的解决办法，您将在后面的部分（即我们在讨论导入物理类型时的部分）中看到这一点。