Modelica-机械示例

机械示例

22 次浏览	1次

如果您对机械系统更为熟悉，那么这个示例会有助于巩固我们迄今为止学过的一些概念。我们希望建模的系统如以下图所示：

值得指出的是，以示意图的形式来呈现模型，表达其目的会容易得多。只要采用恰当的图形表示，专家们就能很快理解系统的构成，并对其运行方式形成直观的认识。虽然我们目前主要关注方程和变量，但最终我们会逐步过渡到一种方法（即将在关于组件的章节中介绍的），即从一开始就以这种图表形式构建模型。

不过目前，我们还是先专注于如何表达与这个简单机械系统相关的方程式吧。每个惯性元件都有一个旋转位置，和一个旋转速度，其中对于每一个惯性，该惯性矩的角动量平衡关系可以表示为：

换句话说，作用于惯性的扭矩总和应该等于转动惯量与角加速度的乘积。

目前，我们所欠缺的只有扭矩值和。从之前的图中我们可以看出，有两根弹簧和两个减震器。对于弹簧，我们可以利用胡克定律来表示扭矩与角度位移之间的关系，具体如下：

对于每个减震器，我们将其扭矩与相对角速度之间的关系表示为：

如果我们将所有这些关系综合起来，就会得到以下方程组：

假设我们的系统还具有以下初始条件：

这些初始条件实际上意味着，系统初始时处于一种状态，即既没有惯性物体在移动（即“WWW”状态），但两个弹簧之间却存在非零的偏移量。

将所有这些变量和方程式综合起来，我们可以在 Modelica 中将此问题表述如下：

model SecondOrderSystem "A second order rotational system"
  type Angle=Real(unit="rad");
  type AngularVelocity=Real(unit="rad/s");
  type Inertia=Real(unit="kg.m2");
  type Stiffness=Real(unit="N.m/rad");
  type Damping=Real(unit="N.m.s/rad");
  parameter Inertia J1=0.4 "Moment of inertia for inertia 1";
  parameter Inertia J2=1.0 "Moment of inertia for inertia 2";
  parameter Stiffness c1=11 "Spring constant for spring 1";
  parameter Stiffness c2=5 "Spring constant for spring 2";
  parameter Damping d1=0.2 "Damping for damper 1";
  parameter Damping d2=1.0 "Damping for damper 2";
  Angle phi1 "Angle for inertia 1";
  Angle phi2 "Angle for inertia 2";
  AngularVelocity omega1 "Velocity of inertia 1";
  AngularVelocity omega2 "Velocity of inertia 2";
initial equation
  phi1 = 0;
  phi2 = 1;
  omega1 = 0;
  omega2 = 0;
equation
  // Equations for inertia 1
  omega1 = der(phi1);
  J1*der(omega1) = c1*(phi2-phi1)+d1*der(phi2-phi1);
  // Equations for inertia 2
  omega2 = der(phi2);
  J2*der(omega2) = c1*(phi1-phi2)+d1*der(phi1-phi2)-c2*phi2-d2*der(phi2);
end SecondOrderSystem;

正如我们在低通滤波器示例中所做的那样（即 RLC1），接下来我们将逐行详细讲解这个内容。

和往常一样，我们先从模型的名称说起：

model SecondOrderSystem "A second order rotational system"

接下来，我们为旋转机械系统介绍其物理类型，具体包括：

  type Angle=Real(unit="rad");
  type AngularVelocity=Real(unit="rad/s");
  type Inertia=Real(unit="kg.m2");
  type Stiffness=Real(unit="N.m/rad");
  type Damping=Real(unit="N.m.s/rad");

然后，我们定义了用于描述我们系统不同物理特性的各种参数：

  parameter Inertia J1=0.4 "Moment of inertia for inertia 1";
  parameter Inertia J2=1.0 "Moment of inertia for inertia 2";
  parameter Stiffness c1=11 "Spring constant for spring 1";
  parameter Stiffness c2=5 "Spring constant for spring 2";
  parameter Damping d1=0.2 "Damping for damper 1";
  parameter Damping d2=1.0 "Damping for damper 2";

对于这个系统，有四个非参数变量。它们的定义如下：

  Angle phi1 "Angle for inertia 1";
  Angle phi2 "Angle for inertia 2";
  AngularVelocity omega1 "Velocity of inertia 1";
  AngularVelocity omega2 "Velocity of inertia 2";

随后，通过以下方式来定义初始条件（稍后我们将对此进行回顾）

initial equation
  phi1 = 0;
  phi2 = 1;
  omega1 = 0;
  omega2 = 0;

接下来便是描述系统动态响应的方程式：

equation
  // Equations for inertia 1
  omega1 = der(phi1);
  J1*der(omega1) = c1*(phi2-phi1)+d1*der(phi2-phi1);
  // Equations for inertia 2
  omega2 = der(phi2);
  J2*der(omega2) = c1*(phi1-phi2)+d1*der(phi1-phi2)-c2*phi2-d2*der(phi2);

最后，我们完成了模型定义的部分。

end SecondOrderSystem;

该模型唯一的缺点在于，我们所有的初始条件都已被“硬编码”进模型中。这意味着我们将无法为该模型指定任何其他初始条件的组合。我们可以通过定义参数变量来表示初始条件（就像我们在牛顿冷却的例子中所做的那样）来解决这个问题：

model SecondOrderSystemInitParams
  "A second order rotational system with initialization parameters"
  type Angle=Real(unit="rad");
  type AngularVelocity=Real(unit="rad/s");
  type Inertia=Real(unit="kg.m2");
  type Stiffness=Real(unit="N.m/rad");
  type Damping=Real(unit="N.m.s/rad");
  parameter Angle phi1_init = 0;
  parameter Angle phi2_init = 1;
  parameter AngularVelocity omega1_init = 0;
  parameter AngularVelocity omega2_init = 0;
  parameter Inertia J1=0.4 "Moment of inertia for inertia 1";
  parameter Inertia J2=1.0 "Moment of inertia for inertia 2";
  parameter Stiffness c1=11 "Spring constant for spring 1";
  parameter Stiffness c2=5 "Spring constant for spring 2";
  parameter Damping d1=0.2 "Damping for damper 1";
  parameter Damping d2=1.0 "Damping for damper 2";
  Angle phi1 "Angle for inertia 1";
  Angle phi2 "Angle for inertia 2";
  AngularVelocity omega1 "Velocity of inertia 1";
  AngularVelocity omega2 "Velocity of inertia 2";
initial equation
  phi1 = phi1_init;
  phi2 = phi2_init;
  omega1 = omega1_init;
  omega2 = omega2_init;
equation
  omega1 = der(phi1);
  omega2 = der(phi2);
  J1*der(omega1) = c1*(phi2-phi1)+d1*der(phi2-phi1);
  J2*der(omega2) = c1*(phi1-phi2)+d1*der(phi1-phi2)-c2*phi2-d2*der(phi2);
end SecondOrderSystemInitParams;

这样一来，参数值就可以在模拟环境中进行更改（参数通常可以由用户进行编辑）或者，正如我们稍后看到的那样，也可以通过所谓的“修改”来进行更改。

在该模型的最新版本中，您会发现新引入的参数的值与之前使用的硬编码值相同。因此，默认的初始条件将与之前完全相同。但现在，我们也有机会探索其他初始条件。例如，如果我们像原来那样模拟“SecondOrderSystemInitParams”模型，就会得到以下关于角位置和角速度的解：

然而，如果在模拟开始时将 phi1_init 参数设为 1，我们就会得到这样的结果：

22 次浏览	1次

< 首页

< 下一页