Modelica-速度测量

速度测量

103 次浏览	4次

基准系统

在许多应用中，我们需要对连续行为和离散行为之间的相互作用进行建模。在本节中，我们将探讨用于测量旋转轴速度的技术。在本节讨论中，我们将再次使用之前在基本方程讨论中提到的机械示例：

model SecondOrderSystem "A second order rotational system"
  type Angle=Real(unit="rad");
  type AngularVelocity=Real(unit="rad/s");
  type Inertia=Real(unit="kg.m2");
  type Stiffness=Real(unit="N.m/rad");
  type Damping=Real(unit="N.m.s/rad");
  parameter Inertia J1=0.4 "Moment of inertia for inertia 1";
  parameter Inertia J2=1.0 "Moment of inertia for inertia 2";
  parameter Stiffness c1=11 "Spring constant for spring 1";
  parameter Stiffness c2=5 "Spring constant for spring 2";
  parameter Damping d1=0.2 "Damping for damper 1";
  parameter Damping d2=1.0 "Damping for damper 2";
  Angle phi1 "Angle for inertia 1";
  Angle phi2 "Angle for inertia 2";
  AngularVelocity omega1 "Velocity of inertia 1";
  AngularVelocity omega2 "Velocity of inertia 2";
initial equation
  phi1 = 0;
  phi2 = 1;
  omega1 = 0;
  omega2 = 0;
equation
  // Equations for inertia 1
  omega1 = der(phi1);
  J1*der(omega1) = c1*(phi2-phi1)+d1*der(phi2-phi1);
  // Equations for inertia 2
  omega2 = der(phi2);
  J2*der(omega2) = c1*(phi1-phi2)+d1*der(phi1-phi2)-c2*phi2-d2*der(phi2);
end SecondOrderSystem;

我们将通过在模型中添加一个“extends”子句来复用此模型。这实际上是从我们所扩展的模型中导入所有内容。稍后在讨论包时，我们会更详细地介绍“extends”子句。目前，只需将其视为将另一个模型的内容复制到当前模型中。

回想一下 SecondOrderSystem 模型的解法如下所示：

在这种情况下，我们只是在绘制我们计算出的解图。但在实际系统中，我们无法直接得知轴的旋转速度。相反，我们必须对其进行测量。但测量会引入误差，而且每种测量技术都会带来不同的误差类型。在这一部分，我们将探讨如何对不同类型的测量技术进行建模。

采样保持

我们将要探讨的第一种测量方法是“采样与保持”测量法。一些速度传感器配备了用于测量系统转速的电路。但它们并非提供速度的连续值，而是会在特定时间点对其进行采样，然后将其存储在某个地方。这被称为“采样与保持”。下面的模型展示了如何采用采样与保持的方法来测量角速度 omega1：

model SampleAndHold "Measure speed and hold"
  extends BasicEquations.RotationalSMD.SecondOrderSystem;
  parameter Real sample_time(unit="s")=0.125;
  discrete Real omega1_measured;
equation
  when sample(0,sample_time) then
    omega1_measured = omega1;
  end when;
end SampleAndHold;

请注意在“omega1_measured”的声明中存在这种离散限定词。这种特殊的限定词表明所指定的变量没有连续的解。相反，该变量的值在模拟过程中只会进行（仅有的）离散跳跃。虽然不需要包含“discrete”关键字，但包含它是有用的，因为它能为编译器提供有关模型意图的额外信息，编译器可以据此进行检查（例如，确保我们永远不会请求该变量的导数）。

现在让我们来审视一下这个模型所得出的解决方案：

在该解决方案中，需要注意的重要一点是测量值是分段恒定的。这是因为只有当“when”语句生效时，omega1_measured 的值才会被设定。该示例函数是一个特殊的内置函数，它首先在第一个参数（在此例中为 0）所指示的时间点变为真，然后在之后的固定时间间隔内持续为真。这些固定时间间隔的持续时间由第二个参数（在此例中为 sample_time）来表示。

区间测量

在前面的示例中，我们实际上并未对速度进行任何估算，我们只是在特定时间点报告变量 omega1 的值而已。换句话说，在我们采集 omega1 的数据时，我们的样本是完全准确的。但通过“holding”我们所测量的值（而非继续跟踪 omega1），我们在测量中引入了一些误差。

在接下来的示例中，我们将重点介绍用于估算旋转轴转速的技术。在这些情况下，我们在测量过程中绝不会直接使用实际的转速。相反，我们将响应由物理系统产生的事件，并尝试利用这些事件来重建旋转速度的估计值。

我们将要处理的这些事件是由安装在旋转轴上的离散元件产生的。例如，产生这些事件的一种常见方法是使用“齿轮编码器”。齿轮编码器包含一个安装在旋转轴上的齿轮。在齿轮的两侧，我们放置一个光源和一个光传感器。当齿轮上的齿经过光源时，它们会挡住光线。结果是，光传感器发出的信号将包含一个近似的方波。这些方波的前沿就是我们将要响应的事件。

我们将要探讨的第一种估算方法是通过测量事件之间的时间间隔来计算轴的转速。我们知道，每当轴旋转的角度达到时，这些事件就会发生，因此我们可以这样估算转速：

这种速度估算技术可以用 Modelica 语言表示为：这种速度估算技术可以用 Modelica 语言表示为：

model IntervalMeasure "Measure interval between teeth"
  extends BasicEquations.RotationalSMD.SecondOrderSystem;
  parameter Integer teeth=200;
  parameter Real tooth_angle(unit="rad")=2*3.14159/teeth;
  Real next_phi, prev_phi;
  Real last_time;
  Real omega1_measured;
initial equation
  next_phi = phi1+tooth_angle;
  prev_phi = phi1-tooth_angle;
  last_time = time;
equation
  when {phi1>=pre(next_phi),phi1<=pre(prev_phi)} then
    omega1_measured = tooth_angle/(time-pre(last_time));
    next_phi = phi1+tooth_angle;
    prev_phi = phi1-tooth_angle;
    last_time = time;
  end when;
end IntervalMeasure;

其中“tooth_angle”代表。请注意，“tooth_angle”并非是用户需要指定的参数。相反，用户通过“teeth”参数来指定齿的数量。然后，会使用“teeth”参数的值来计算“tooth_angle”参数（请注意，虽然我们在这里手动设置了这里的值，但在本书后面讨论常量时，我们将学习如何避免这种情况）。

让我们仔细看看这个模型中的“if”语句：

equation
  when {phi1>=pre(next_phi),phi1<=pre(prev_phi)} then
    omega1_measured = tooth_angle/(time-pre(last_time));
    next_phi = phi1+tooth_angle;
    prev_phi = phi1-tooth_angle;
    last_time = time;
  end when;

在这里，我们使用了之前在“弹跳球”示例中所使用的向量表达式语法。请回想一下，当任何一个条件变为真时，条件语句就会生效。在本例中，条件语句会在角度 phi1 大于 next_phi 或小于 prev_phi 时生效。

另外需要注意的是，在“when”语句中对前置运算符的使用。当模型中发生某个事件时，某些变量的值有可能会出现不连续的变化。在事件发生期间，当我们试图确定由于该事件而所有变量应具有的值时，前置运算符使我们能够引用事件发生之前的变量值。在该模型中，前置运算符用于引用“next_phi”、“prev_phi”和“last_time”变量的先前（即事件发生前）值。前置运算符是必要的，因为所有这些变量都受到“当”语句内部语句的影响。例如，如果没有前置运算符，last_time 指的是事件结束时 last_time 的值，而 pre(last_time) 则指的是任何事件发生之前 last_time 的值。

“pre”运算符的使用

一般来说，如果某个变量是由于“when”语句生效而发生变化，那么在与该“when”语句相关的条件表达式中提及该变量时，您几乎总是需要使用“pre ”运算符（就像我们在前面的例子中所做的那样）。这样做能清楚地表明您是在对“ when”语句触发之前所发生的情况做出响应。

让我们来看看这种方法给出的速度估算值：

该估计算法具有两个重要的特性，从这些结果中我们能够立即看出。首先是该估计值是无符号的。换句话说，通过像齿轮编码器这样的设备，我们无法确定轴是朝哪个方向旋转的。此外，低转速以及旋转方向的变化会显著降低估计的准确性。结果还非常依赖所涉及的齿数。如果我们将编码器中的齿数减少到 20 个，就会得到截然不同的结果。

要确切理解为何测量信号如此不准确，不妨参考下面的图表，该图表展示了角度 phi1 与相邻齿所对应的角度（即 next_phi 和 prev_phi）之间的关系。

在这一图中，我们可以清晰地看到，相对较低的速度以及速度的反转是如何导致出现不规则现象的，而这些现象又会引入较大的估算误差。

脉冲计数

上述提到的间隔测量技术需要具备能在硬件中断时进行速度计算的硬件。另一种估算速度的方法是计算在给定（固定）的时间间隔内发生的事件数量，并将其作为速度的估计值。使用这种方法时，只有在事件发生时才进行事件的累加，而计算则会定期安排进行更新。

基于本节前面的示例，以下内容似乎是一种实现这种估算技术的自然方法：

model Counter "Count teeth in a given interval"
  extends BasicEquations.RotationalSMD.SecondOrderSystem;
  parameter Real sample_time(unit="s")=0.125;
  parameter Integer teeth=200;
  parameter Real tooth_angle(unit="rad")=2*3.14159/teeth;
  Real next_phi, prev_phi;
  Integer count;
  Real omega1_measured;
initial equation
  next_phi = phi1+tooth_angle;
  prev_phi = phi1-tooth_angle;
  count = 0;
equation
  when {phi1>=pre(next_phi),phi1<=pre(prev_phi)} then
    next_phi = phi1+tooth_angle;
    prev_phi = phi1-tooth_angle;
    count = pre(count) + 1;
  end when;
  when sample(0,sample_time) then
    omega1_measured = pre(count)*tooth_angle/sample_time;
    count = 0 "Another equation for count?";
  end when;
end Counter;

然而，这个模型存在一个问题。请注意，对于“计数”这个变量实际上有两组方程。试图构建这样一个模型会导致出现方程数量多于变量数量的情况（即问题会变得奇异）。

那么，我们该如何解决这个问题呢？我们需要两个不同的方程式，因为计数的更新是因不同的事件而发生的。我们可以尝试将所有内容都包含在一个单一的“当...时”语句中，比如这样：

when {phi1>=pre(next_phi),phi1<=pre(prev_phi),sample(0,sample_time)} then
  if sample(0,sample_time) then
    omega1_measured := pre(count)*tooth_angle/sample_time;
    count :=0;
  else
    next_phi := phi1 + tooth_angle;
    prev_phi := phi1 - tooth_angle;
    count :=pre(count) + 1;
  end if;
end when;

但这种代码很快就会变得难以阅读。幸运的是，我们可以通过将所有的“当...时”语句放在一个算法部分来解决这个问题。

算法部分的性质在于，对于其内部所赋值的任何变量，都将其视为一个单独的方程式来处理。这使得可以对多次赋值进行计数，例如。在使用算法部分时，非常重要的是要明白赋值的顺序变得很重要。如果出现冲突（例如，在同一个算法部分中一个变量被赋予了两个值），那么最后的那个值将会被使用。关于算法部分的另一点需要注意的是，你不能编写通用的方程式。相反，你必须编写赋值语句。

这样一来，算法部分与大多数编程语言的运作方式非常相似。算法部分中的语句是按顺序执行的，每个语句并非被解读为一个等式，而是被视为将一个表达式赋值给一个变量。赋值语句的熟悉性可能会让具有编程背景的人觉得使用算法部分很有吸引力，因为他们发现模型机（Modelica）中以等式为导向的其他方面让他们感到困惑和不熟悉。但要注意，避免使用算法部分的一个主要原因是，它们会干扰模型机编译器进行的符号运算。这可能会导致模拟性能不佳以及模型组合方式灵活性的丧失。因此，尽可能情况下最好使用等式部分。

就我们的情况而言，使用算法部分并不会产生什么重大影响。下面是一个示例，展示了如何通过使用算法部分来对之前的估算算法进行重构：

model CounterWithAlgorithm "Count teeth in a given interval using an algorithm"
  extends BasicEquations.RotationalSMD.SecondOrderSystem;
  parameter Real sample_time(unit="s")=0.125;
  parameter Integer teeth=200;
  parameter Real tooth_angle(unit="rad")=2*3.14159/teeth;
  Real next_phi, prev_phi;
  Integer count;
  Real omega1_measured;
initial equation
  next_phi = phi1+tooth_angle;
  prev_phi = phi1-tooth_angle;
  count = 0;
algorithm
  when {phi1>=pre(next_phi),phi1<=pre(prev_phi)} then
    next_phi := phi1 + tooth_angle;
    prev_phi := phi1 - tooth_angle;
    count := pre(count) + 1;
  end when;
  when sample(0,sample_time) then
    omega1_measured := pre(count)*tooth_angle/sample_time;
    count :=0;
  end when;
end CounterWithAlgorithm;

该估算技术的模拟结果可参考以下图表：

同样，我们发现这种方法无法确定旋转的方向。通过下面的图表，我们可以大致了解每个样本区间内发生了多少次事件：

一般来说，在一个区间内数值越大，估计的准确性就越高。

结论

本节展示了如何利用“当”语句来应对我们系统中发生的物理事件。这类事件及其对系统产生的影响与我们之前所探讨的连续动态变化同样重要。能够捕捉并响应这些物理事件是 Modelica 能够很好地适用于完整系统模型的重要原因，因为这些系统通常包含连续和离散两种行为。

103 次浏览	4次

< 首页

< 下一页