Modelica-滞后效应

108 次浏览	4次

在本节中，我们将讨论滞后这一主题。对于某些类型的建模来说，理解这一概念十分重要。回想一下我们在前面关于状态事件处理的讨论中看到的情况，当时出现了抖振现象。在那些情况下，我们能够使用 noEvent 操作符来解决该问题，因为抖振纯粹是对数值噪声的响应，而非由行为的突然变化所引发。

在本节中，我们将考虑一个稍微极端一点的情况。考虑以下模型：

model ChatteringControl "A control strategy that will 'chatter'"
  type HeatCapacitance=Real(unit="J/K");
  type Temperature=Real(unit="K");
  type Heat=Real(unit="W");
  type Mass=Real(unit="kg");
  type HeatTransferCoefficient=Real(unit="W/K");
  Boolean heat "Indicates whether heater is on";
  parameter HeatCapacitance C=1.0;
  parameter HeatTransferCoefficient h=2.0;
  parameter Heat Qcapacity=25.0;
  parameter Temperature Tamb=285;
  parameter Temperature Tbar=295;
  Temperature T;
  Heat Q;
initial equation
  T = Tbar+5;
equation
  heat = T<Tbar;
  Q = if heat then Qcapacity else 0;
  C*der(T) = Q-h*(T-Tamb);
end ChatteringControl;

如果我们对这个模型进行模拟，会得到以下结果：

然而，得出这些结果的模拟过程需要耗费极长的时间才能完成。要更好地理解这种糟糕的模拟效果，可以通过查看模拟过程中加热器的输出情况来加以理解：

您所看到的是，在大约 0.2 秒后，加热器会不断地开启和关闭。这种情况发生得如此频繁，以至于实际上您需要将图表放大很多倍才能看到这些转换过程。如果采用常规缩放方式，由于转换次数太多，结果会看起来像一个填充的矩形。

这实际上在控制系统中是一个真实存在的问题。如果你仔细观察一下自己家中炉子的工作方式，就会发现它不会随着室温的升高和降低而持续不断地开启和关闭。相反，它会等到温度达到某个特定数值（高于或低于你所设定的室温）时才开始工作。

在设定温度附近出现的这一“波动”现象被称为滞后现象。而“抖动控制”模型的问题在于它完全没有这种滞后现象。相反，该模型会根据温度的微小变化持续地开启和关闭加热器。

模拟滞后现象的难点在于它具有“状态性”。系统的行为取决于过去发生的事情。因此，我们不能简单地使用 if 语句。原因在于 if 语句只考虑系统的当前状态，而不会考虑其他因素。为了实现滞后效应，我们需要使用 when 语句。请看下面的模型：

model HysteresisControl "A control strategy that doesn't chatter"
  type HeatCapacitance=Real(unit="J/K");
  type Temperature=Real(unit="K");
  type Heat=Real(unit="W");
  type Mass=Real(unit="kg");
  type HeatTransferCoefficient=Real(unit="W/K");
  Boolean heat(start=false) "Indicates whether heater is on";
  parameter HeatCapacitance C=1.0;
  parameter HeatTransferCoefficient h=2.0;
  parameter Heat Qcapacity=25.0;
  parameter Temperature Tamb=285;
  parameter Temperature Tbar=295;
  Temperature T;
  Heat Q;
initial equation
  T = Tbar+5;
  heat = false;
equation
  Q = if heat then Qcapacity else 0;
  C*der(T) = Q-h*(T-Tamb);
  when {T>Tbar+1,T<Tbar-1} then
    heat = T<Tbar;
  end when;
end HysteresisControl;

仔细研究这些“当...时”语句，我们发现系统只有在“T>Tbar+1”变为真或者“T<Tbar-1”变为真时才会做出响应。需要注意的是，当这些表达式变为假时，不会有任何反应发生。这就是为什么“if”语句无法发挥作用的原因。使用“if”语句或“if”表达式时，行为会随着条件表达式的改变而改变。但使用“当...时”语句时，当条件变为真时，“当...时”语句中的语句才会生效。如果我们模拟这个模型并观察温度，就会发现它始终处于我们期望温度的滞回带内。

更重要的是，如果我们查看系统的热量输出情况，就会发现与我们之前的例子不同的是，加热器开启和关闭之间存在一段时间间隔。

通过使用算法部分（正如我们在关于速度估算技术的讨论中之前所阐述的那样），可以将实现滞后效应的逻辑表述得更加清晰明了。

model HysteresisControlWithAlgorithms "Control using algorithms"
  type HeatCapacitance=Real(unit="J/K");
  type Temperature=Real(unit="K");
  type Heat=Real(unit="W");
  type Mass=Real(unit="kg");
  type HeatTransferCoefficient=Real(unit="W/K");
  Boolean heat "Indicates whether heater is on";
  parameter HeatCapacitance C=1.0;
  parameter HeatTransferCoefficient h=2.0;
  parameter Heat Qcapacity=25.0;
  parameter Temperature Tamb=285;
  parameter Temperature Tbar=295;
  Temperature T;
  Heat Q;
initial equation
  T = Tbar+5;
  heat = false;
equation
  Q = if heat then Qcapacity else 0;
  C*der(T) = Q-h*(T-Tamb);
algorithm
  when T<Tbar-1 then
    heat :=true;
  end when;
  when T>Tbar+1 then
    heat :=false;
  end when;
end HysteresisControlWithAlgorithms;

请注意，这两个条件表达式已被拆分为两个独立的“when”语句。这样就清晰地表明了导致加热开关开启和关闭的原因。这些“when”语句被放置在算法部分，因为它们都对同一个变量“heat”进行赋值。

108 次浏览	4次

< 首页

< 下一页