环境条件的变化

我们将从一个简单的示例开始，该示例演示时间事件。我们将再次使用之前在物理类型部分介绍的热模型。不过，这次我们将对该系统引入一个干扰。具体来说，我们将在模拟半秒后触发环境温度的突然下降。这个修改后的模型如下所示：

model NewtonCoolingDynamic
  "Cooling example with fluctuating ambient conditions"
  // Types
  type Temperature=Real(unit="K", min=0);
  type ConvectionCoefficient=Real(unit="W/(m2.K)", min=0);
  type Area=Real(unit="m2", min=0);
  type Mass=Real(unit="kg", min=0);
  type SpecificHeat=Real(unit="J/(K.kg)", min=0);

  // Parameters
  parameter Temperature T0=363.15 "Initial temperature";
  parameter ConvectionCoefficient h=0.7 "Convective cooling coefficient";
  parameter Area A=1.0 "Surface area";
  parameter Mass m=0.1 "Mass of thermal capacitance";
  parameter SpecificHeat c_p=1.2 "Specific heat";

  // Variables
  Temperature T_inf "Ambient temperature";
  Temperature T "Temperature";
initial equation
  T = T0 "Specify initial value for T";
equation
  if time<=0.5 then
    T_inf = 298.15 "Constant temperature when time<=0.5";
  else
    T_inf = 298.15-20*(time-0.5) "Otherwise, decreasing";
  end if;
  m*c_p*der(T) = h*A*(T_inf-T) "Newton's law of cooling";
end NewtonCoolingDynamic;

高亮显示的行展示了一个 if 语句。这个特定的 if 语句为计算 T_inf 提供了两个不同的方程。

Time

您会注意到，在此模型中，变量“Time”并未在我们的模型中进行声明。这是因为时间在所有的 Modelica 模型中都是一个内置变量。

关于究竟使用哪两个方程这一决定，取决于条件表达式 time<=0.5 的值。这是因为这个表达式仅与时间有关，而不涉及我们模型中的任何其他变量，所以我们可以将这两个方程之间的转换描述为“时间事件”。关键在于，在对这些方程进行积分时，我们可以告知负责整合我们方程系统的求解器，在 0.5 秒时精确停止，然后使用另一个方程重新开始。在下一节中，当我们展示经典的“弹球”示例时，我们将看到在某些情况下这种做法是不可行的其他状态事件的例子。

正如您在这些结果中所看到的，环境温度在半秒后确实开始下降。在研究温度本身的动态响应时，我们观察到了两个不同的阶段。第一个阶段是朝着平衡状态（以匹配环境温度）的初始瞬态响应。第二个阶段是随着环境温度的下降而对环境温度进行跟踪。

初始瞬态

需要指出的是，这在建模过程中是一个非常常见的问题。通常情况下，您希望对系统对某种干扰（比如在此例中是环境温度的下降）的响应进行建模。然而，如果您的系统没有以某种平衡状态开始，那么系统的响应也会包含某种初始瞬态（如图所示）。为了清晰地区分这两种响应，我们需要避免它们之间的任何重叠。最简单的方法是将模拟从平衡状态开始（正如我们在关于稳态初始化的讨论中之前所讨论的那样）。这样可以完全避免初始瞬态，并使我们能够完全专注于我们感兴趣的干扰因素。

正如我们在关于初始化的讨论中所了解到的，我们可以通过简单地添加一个初始方程来解决初始瞬态的问题，该方程将确定一个 T 的值，使得我们的系统能够以平衡状态开始运行，即

model NewtonCoolingSteadyThenDynamic
  "Dynamic cooling example with steady state conditions"
  type Temperature=Real(unit="K", min=0);
  type ConvectionCoefficient=Real(unit="W/(m2.K)", min=0);
  type Area=Real(unit="m2", min=0);
  type Mass=Real(unit="kg", min=0);
  type SpecificHeat=Real(unit="J/(K.kg)", min=0);

  parameter ConvectionCoefficient h=0.7 "Convective cooling coefficient";
  parameter Area A=1.0 "Surface area";
  parameter Mass m=0.1 "Mass of thermal capacitance";
  parameter SpecificHeat c_p=1.2 "Specific heat";

  Temperature T_inf "Ambient temperature";
  Temperature T "Temperature";
initial equation
  der(T) = 0 "Steady state initial conditions";
equation
  if time<=0.5 then
    T_inf = 298.15 "Constant temperature when time<=0.5";
  else
    T_inf = 298.15-20*(time-0.5) "Otherwise, decreasing";
  end if;
  m*c_p*der(T) = h*A*(T_inf-T) "Newton's law of cooling";
end NewtonCoolingSteadyThenDynamic;

我们唯一做出的改变就是改变了初始方程。我们不再让系统从某个固定的温度状态开始，而是从一个温度出发，使得温度的变化（至少在我们施加干扰之前）为零。现在，温度响应不再包含任何初始的瞬态部分，我们可以只关注对干扰的响应：

紧凑性

if 语句的一个问题在于，它们可能会使原本相对简单的行为变化显得相当复杂。我们可以使用几种替代结构来用更少的代码实现相同的功能。

第一种方法是使用 if 表达式。与 if 语句包含包含方程的“分支”不同，if 表达式的分支中仅包含表达式。此外，if 表达式的语法也更为简洁。如果我们选择使用 if 表达式，我们的方程可以简化为：

equation
  T_inf = 298.15 - (if time<0.5 then 0 else 20*(time-0.5));
  m*c_p*der(T) = h*A*(T_inf-T) "Newton's law of cooling";

或者，我们可以使用 Modelica 系统中众多内置函数中的一个，比如“max”函数，来表示环境温度的变化，例如：

equation
  T_inf = 298.15 - max(0, 20*(time-0.5));
  m*c_p*der(T) = h*A*(T_inf-T) "Newton's law of cooling";

事件

我们已经看到了几种表达系统行为突然发生变化的方式。但需要指出的是，我们不仅是在描述环境温度的变化，我们还指明了这种变化发生的时间。这是一个微妙但非常重要的点。

来看最后一个例子，在这个例子中，我们的系统最初处于平衡状态。在模拟开始时，系统中并没有明显的动态变化。由于系统中实际上没有发生什么变化，所以积分器不太可能累积较大的积分误差。因此，为了尽可能缩短完成模拟所需的时间，在这种情况下，变量步长积分器将会增大其步长。

然而，这样做存在一定的风险。风险在于集成商可能会因系统突然出现的干扰而措手不及。如果这种干扰真的发生，集成商认为大步骤不会导致显著的集成误差的这一假设将不再成立。

那么问题就来了，积分器如何才能知道何时可以采用较大的时间步长，何时又不能这样做呢。通常，这些积分方案采用一种试错的方法。它们先尝试采用较大的步长，然后估算该步长所引入的误差量。如果该误差量小于某个阈值，那么它们就会接受当前的状态（或者也许会尝试更大的步长）。反之，如果该步长引入的误差过大，那么它们就会尝试更小的步长。但它们无法知道要使误差量低于阈值所需的步长到底应该是多小，这意味着它们将继续盲目地尝试越来越小的步长。

但 Modelica 的作用远不止于整合底层系统。Modelica 编译器会研究问题的结构。在我们所有的示例中，编译器都能发现行为存在明显的变化。不仅如此，它还能看出这种行为上的变化是一个时间事件，即一个其发生时间事先已知、且无需了解求解轨迹即可确定的事件。

因此，Modelica 编译器的作用是告知底层的积分器，在 0.5 秒时行为会有突然的变化，并指示积分器仅在该时刻之前进行精确积分，之后不再继续积分。这样一来，这种突然的变化就不会在时间步长内发生。相反，积分器会从事件的另一侧重新开始计算。这样就完全避免了盲目地寻找能使步长误差最小的截止时间的过程。相反，积分器会自动一直计算到该点，然后在该点之后重新开始。

这是 Modelica 中众多优化仿真执行方式的特性之一。关于此类处理方式的更详细讨论，请参阅即将出现的“事件”部分。在接下来的章节中，我们还将看到更多依赖于解变量的复杂事件示例。