模拟弹跳球

在上一个示例中，我们看到了某些事件与时间相关。这些所谓的“时间事件”只是事件的一种类型。在本节中，我们将研究另一种类型的事件，即状态事件。状态事件是依赖于解轨迹的事件。

状态事件的处理要复杂得多。与时间事件不同，时间事件的发生时间是事先已知的，而状态事件则取决于解的轨迹。因此，我们无法完全避免对事件发生点进行“搜索”。

要了解状态事件的实际运作情况，让我们来考虑一下在水平平面上弹跳的球的行为。当球在平面上方时，它会因重力作用而加速。当球最终与平面接触时，它会根据以下关系从平面上弹起：

其中 表示球与表面接触后的（垂直）速度， 表示接触前的速度，而 则是碰撞系数，它是衡量碰撞后球所保留动量比例的指标。

将所有这些内容整合到 Modelica 中可能会是这样的情况：

model BouncingBall "The 'classic' bouncing ball model"
  type Height=Real(unit="m");
  type Velocity=Real(unit="m/s");
  parameter Real e=0.8 "Coefficient of restitution";
  parameter Height h0=1.0 "Initial height";
  Height h "Height";
  Velocity v(start=0.0, fixed=true) "Velocity";
initial equation
  h = h0;
equation
  v = der(h);
  der(v) = -9.81;
  when h<0 then
    reinit(v, -e*pre(v));
  end when;
end BouncingBall;

在这个例子中，我们使用参数 h0 来指定球从表面弹起时的初始高度，使用参数 e 来指定弹性系数。变量 h 和 v 分别代表高度和垂直速度。

使这个例子引人入胜之处在于其中的方程式。具体来说，就是存在一个“if”语句：

equation
  v = der(h);
  der(v) = -9.81;
  when h<0 then
    reinit(v, -e*pre(v));
  end when;

一个“when”语句由两部分组成。第一部分是条件表达式，它表明事件发生的时刻。在本例中，事件将在“当高度 h 首次降至 0 以下时”发生。当语句的第二部分是事件发生时所要执行的操作。在本例中，v 的值通过 reinit 操作符重新初始化。reinit 操作符允许我们为一个状态指定一个新的初始条件。从概念上讲，你可以将 reinit 想象成是在模拟过程中插入的一个初始方程。但它只改变一个变量，并且总是明确地设置（也就是说，它不如初始方程那样灵活）。在这种情况下，reinit 语句将把 v 的值重新初始化为与碰撞前 v 的值相反的方向，并按因子 e 进行缩放。

假设 h0 为正值，重力的持续作用会确保球最终会触碰到表面。对于 h0 为 1.0 的情况进行模拟后，我们从这个模型中观察到以下行为：

在该图中，我们可以看到在大约 0.48 秒时，与表面的首次碰撞发生了。这是因为此时条件 h<0 首次变为真。请注意，使这一情况成为状态事件（与我们之前冷却示例中的情况不同）的原因在于这个条件表达式引用的并非仅仅是时间变量。

因此，该模拟过程假定球处于自由落体状态，直到它确定出一个解决方案轨迹，在该轨迹中条件表达式的值 h<0 在一个时间步长内发生变化。当出现这样的步骤时，求解器必须确定条件表达式值变为真的确切时间。一旦确定了这个时间，它就会计算出该时间点系统的状态，处理当中的“当”语句（例如任何重新初始化语句）以影响系统的状态，然后从这些计算出的状态重新开始积分。对于弹跳球的情况，重新初始化语句用于计算碰撞后的新速度值，使球（最初）再次向上运动。

但需要记住的是，一般来说，大多数 Modelica 模型的解决方案都是通过数值方法得出的。正如我们很快将会看到的，在考虑离散行为时，这会产生一些深远的影响。这是因为所有事件（无论是时间事件还是状态事件）的核心都是条件表达式，比如我们当前示例中的 h<0 。

如果我们将球的弹跳过程模拟得更久一些，其含义就会变得清晰起来。在这种情况下，大多数 Modelica 工具将会给出这样的解决方案：

当观察这条轨迹时，不难看出肯定出了问题。但是呢？

数值精度

正如我们之前所暗示的那样，答案在于对“当条件 h<0 时”的数值处理方式。更具体地说，如果我们从一个极其接近事件的状态开始，我们应该怎么做？由于数值的不精确性，我们不知道我们是在事件刚刚发生之后开始进行一步操作，还是是在事件即将发生时开始进行一步操作。

为了解决这个问题，我们必须引入一定的滞后效应（死区）。在这种情况下，这意味着一旦条件 h<0 成立，我们必须先远离该条件“足够远”之后，才能再次允许该事件发生。换句话说，只要 h 小于零，事件就会发生。但在我们再次触发该事件之前，我们要求 h 必须首先大于某个值 。换句话说，并非仅仅 h 变为大于零就足够了，而是必须大于 （其中 是由求解器通过检查各种缩放因子来确定的）。

在之前的模拟中存在这样一个问题：每次球弹起时，h 的峰值都会略微降低一点。这里所说的峰值是指球再次开始下落时的 h 值。最终，h 的峰值不足以超过 的临界值。这也就意味着当语句永远不会触发，而重新初始化语句也永远不会再次重置 v。因此，球会无限期地处于自由落体状态。

因此，这就引出了一个显而易见的问题：如何才能实现我们原本想要达到的效果（即球体始终不会跌落到表面之下）呢？为此，我们需要对我们的模型做一些小的调整，具体如下：

model StableBouncingBall
  "The 'classic' bouncing ball model with numerical tolerances"
  type Height=Real(unit="m");
  type Velocity=Real(unit="m/s");
  parameter Real e=0.8 "Coefficient of restitution";
  parameter Height h0=1.0 "Initial height";
  constant Height eps=1e-3 "Small height";
  Boolean done "Flag when to turn off gravity";
  Height h "Height";
  Velocity v(start=0.0, fixed=true) "Velocity";
initial equation
  h = h0;
  done = false;
equation
  v = der(h);
  der(v) = if done then 0 else -9.81;
  when {h<0,h<-eps} then
    done = h<-eps;
    reinit(v, -e*(if h<-eps then 0 else pre(v)));
  end when;
end StableBouncingBall;

需要指出的是，解决这个问题的方法有很多。这里所介绍的解决方案只是其中的一种。在这种方法中，我们实际上创建了两个表面。一个位于 0 的高度，另一个位于 -eps 的高度（略低于 0）。当球“正常”弹跳时，它只会触发我们“when”语句中的第一个条件。然而，如果球在接触后反弹高度不够，并且“穿过”了第一个表面，我们会检测到这一点（以及它已经穿过表面这一事实）并设置“done”标志。“done”标志的作用是有效地关闭重力。

请注意此情况下“when”的语句结构：

  when {h<0,h<-eps} then
    done = h<-eps;
    reinit(v, -e*(if h<-eps then 0 else pre(v)));
  end when;

特别要注意的是，它并非只有一个条件表达式，而是有两个。更确切地说，它实际上是一个条件表达式的集合。我们将在本书后面部分介绍向量和数组，但目前重要的是要指出，在本章中我们已经表明，当语句既可以包含一个标量条件表达式，也可以包含一个条件表达式的集合。

如果一个“when”语句包含一个条件语句的集合，那么当集合中的任何一个条件表达式变为真时，该“when”语句中的语句就会被触发。请注意仔细阅读这段解释的语法。在阅读模型库（Modelica）代码时，人们经常会这样读：

when {a>0, b>0} then
  ...
end when;

“当 a 大于零或者 b 大于零时”。但非常重要的是，切勿犯一个常见的错误，即错误地将此理解为以下这两个“when”语句是等价的：

>when {a>0, b>0} then
  ...
end when;

when a>0 or b>0 then
  ...
end when;

这些并不相同。要理解其中的差异，我们不妨将条件表达式作如下修改：

when {time>1, time>2} then
  ...
end when;

when time>1 or time>2 then
  ...
end when;

请记住我们最初的表述：在“when”这一语句中所使用的向量符号意味着，在“ when ”语句中的所有条件变为真时，这些条件所对应的语句就会被触发。假设我们进行一个从time=0 开始、一直运行到time=3 的模拟，那么这个“ when ”语句：

when {time>1, time>2} then
  ...
end when;

将会被触发两次。一次是在“time>1 ”变为真时，另一次是在“time>2”变为真时。相比之下，在这种情况下：

when time>1 or time>2 then
  ...
end when;

这里只有一个条件表达式，且该表达式仅在一次时为真（当 time>1 成为真……并且一直保持为真）。或者运算符实际上掩盖了第二个条件（time>2），使得在特定情况下它甚至可能根本不存在。换句话说，这个条件仅在一次时为真。因此，当语句内部的代码只有在这一情况下才会被触发一次。

需要记住的关键点是：对于“ when”的语句，一个条件语句集合意味着“任何”情况，而非“或”情况。此外，这些语句只有在条件变为真时才会生效。这一最后的陈述的含义将在本章后面讨论，届时我们将详细阐述“ if ”与“when”之间的重要区别。