让我们来看一个极其简单的微分方程：

观察这个方程，我们看到只有一个变量，该方程可在Modelica中表示为：

model FirstOrder
  Real x;
equation
  der(x) = 1-x;
end FirstOrder;

这段代码以“model”这一关键字开头，该关键字用于表示模型定义的开始。紧随其后的是“model”这一关键字以及模型名称“FirstOrder”。接下来，是对我们所关注的所有变量的声明。

由于我们方程中的变量 显然是一个连续的实数值变量，所以在 Modelica 中对其的声明采用了 Real x； 的形式。Real 类型只是我们可用的多种类型中的一种（关于各种可能类型更完整的描述将在接下来关于变量的章节中进行阐述）。

一旦所有变量都已声明完毕，我们就可以开始引入描述我们模型行为的方程式了。在这种情况下，我们可以使用 der 运算符来表示 x 的时间导数。因此，

der(x) = (1-x)

等同于：

与大多数编程语言不同，我们不会将代码视为一个“程序”，将其理解为一系列需依次执行的指令。相反，我们使用 Modelica 编译器将此模型转换为我们能够进行模拟的形式。这个模拟步骤实质上就是求解（通常是通过数值方法）这个方程，并提供类似这样的解的轨迹：

一阶模拟

这为您初步揭示了使用建模语言来描述数学行为的一个极具吸引力的方面。我们无需描述如何求解这个微分方程。重点完全在于行为本身。在我们逐步处理更复杂的例子时，会发现涉及求解过程的许多繁琐工作都将由 Modelica 编译器自动处理。

添加一些文档

既然我们已经解决了这个简单的数学方程，那么接下来让我们暂时将注意力转向如何让这个模型更具可读性。请看下面这个模型：

model FirstOrderDocumented "A simple first order differential equation"
  Real x "State variable";
equation
  der(x) = 1-x "Drives value of x toward 1.0";
end FirstOrderDocumented;

注意此模型中所引用的文字。

需要明白的是，这些被引用的文本块（在计算机科学中被称为“字符串”）并非注释。它们是“描述性字符串”，与注释不同的是，它们不能随意添加到任何位置。相反，它们只能插入到特定位置，以提供关于与其相关联的模型元素的额外说明。

例如，第一个字符串“一个简单的一阶微分方程”用于描述此内容所代表的模型类型。请注意，它是如何紧跟模型名称之后的。如果您希望为该模型添加此类相关说明，那么必须将其紧接在模型名称之后呈现，如所示。

正如我们稍后将会看到的那样，这种类型的文档可以被各种工具以多种方式使用。例如，在搜索模型时，工具可能会在识别匹配项时使用这些描述性字符串。这段文本也可能与模型的图形表示相关联。当然，这种类型的文档对于任何阅读模型的人来说都非常有用。

正如这个例子所表明的那样，描述性文本还可以出现在其他位置。例如，它可以在变量或方程的声明之后出现，以对其进行说明。

初始化

正如我们之前所看到的，Modelica 允许我们通过微分方程来描述模型的行为。但我们所选择的初始条件与这些方程同样重要。

基于此，Modelica 还提供了用于描述我们方程系统初始化的结构。例如，如果我们希望模型中变量 x 的初始值为 2，我们可以像下面这样在模型中添加一个初始方程部分：

model FirstOrderInitial "First order equation with initial value"
  Real x "State variable";
initial equation
  x = 2 "Used before simulation to compute initial values";
equation
  der(x) = 1-x "Drives value of x toward 1.0";
end FirstOrderInitial;

请注意，此模型与在“添加一些文档说明”部分所介绍的上一个模型之间的唯一区别在于新增了初始方程部分，其中包含方程 x = 2 。在之前的示例中，模拟开始时 x 的初始值未作说明。一般来说，这意味着 x 的初始值将是其“起始属性”的值（默认情况下为零）。然而，由于每个工具都使用其特定的算法来构建最终的方程组，因此最好明确说明初始条件，正如我们在此处所做的那样。通过将此方程添加到初始方程部分，我们明确指定了 x 的初始条件。

因此，解决方案的路径与我们在此图中所看到的截然不同：

指定（非零）初始条件

“第一阶初始值模型”展示了一种典型的系统初始化方式，即通过为系统的状态提供明确的初始值来实现初始化。实际上，一个微分方程组如果没有对初始条件的确定方式做出规定，就是不完整的。我们的“第一阶初始值模型”在数学上可以表示为：

然而，在很多情况下，您可能需要一种更为复杂的初始化方式。初始方程部分不仅可以包含状态变量初始值的显式方程，还可以包含其他相关信息。

例如，我们可能希望在模拟开始时，变量 的导数为零。在这种情况下，只需要进行一些简单的代数运算就能明白，可以通过设定初始条件 来实现这一目标。然而，对于更复杂的系统，要确定能够满足此类要求的初始状态值却绝非易事。在这些情况下，可以将这一约束条件直接用 Modelica 语言表达如下：

model FirstOrderSteady
  "First order equation with steady state initial condition"
  Real x "State variable";
initial equation
  der(x) = 0 "Initialize the system in steady state";
equation
  der(x) = 1-x "Drives value of x toward 1.0";
end FirstOrderSteady;

对该系统进行模拟后得出以下结果：

稳态解（与动态响应之对比）

从这些结果中我们可以看出，在模拟开始时， 的初始导数为零，并且此后一直保持为零，因为该系统没有受到任何外部因素的影响，不会打破这种平衡状态。

这展示了 Modelica 中的初始化功能概览。关于初始化主题更全面的介绍，请参阅本章后面“初始化”部分的内容。

实验条件

在构建模型时，模型开发者可能会希望将特定的实验条件与模型关联起来。这可以通过使用一种叫做“注释”的方式来实现。注释包含了与模型行为无关的信息。

例如，实验条件会描述诸如模拟开始时间、结束时间、解的容差等信息。这些并非关于模型自身行为的信息，而是关于如何进行该行为模拟的信息。实验条件会以一种称为“实验注释”的特定标注形式存储在模型中。

在实验注释中可以指定四条信息。这些信息均为可选内容。以下是我们第一级系统的一个示例，其中包含了实验注释：

model FirstOrderExperiment "Defining experimental conditions"
  Real x "State variable";
initial equation
  x = 2 "Used before simulation to compute initial values";
equation
  der(x) = 1-x "Drives value of x toward 1.0";
  annotation(experiment(StartTime=0,StopTime=8));
end FirstOrderExperiment;

根据这些实验条件，我们模拟出了以下的轨迹：

利用实验注释进行模拟

该轨迹在 8 秒时终止，这是因为模拟器是依据实验注释来确定模拟运行时长的。